getstagetable.sas

Go to the documentation of this file.

/**
  @file getstagetable.sas
  @brief Retrieves the actual table that is being sent for update
  @details Fetches the staged table (unformatted and formatted versions) for
  a submitted change, given its TABLE_ID.
 
  <h4> Service Inputs </h4>
 
  <h5> IWANT </h5>
  |TABLE_ID:$char32.|
  |---|
  |DC20220208T142124517_124703_1184|
 
  <h4> SAS Macros </h4>
  @li dc_assignlib.sas
  @li mf_existds.sas
  @li mp_abort.sas
  @li mp_applyformats.sas
  @li mp_getcols.sas
  @li mp_validatecol.sas
 
  @version 9.2
  @author 4GL Apps Ltd
  @copyright 4GL Apps Ltd.  This code may only be used within Data Controller
    and may not be re-distributed or re-sold without the express permission of
    4GL Apps Ltd.
 
**/
%mpeinit()
 
/* table_id arrives in the web request (work.iwant) and is used in libname,
  set and where statements below - so validate it strictly (must be a valid
  SAS name) before ANY such use, to prevent code injection */
%let table_id=0;
data _null_;
  set work.iwant;
  %mp_validatecol(table_id,ISNAME,is_name)
  if is_name=1 then call symputx('table_id',table_id);
  else putlog 'ERR' 'OR: Invalid table_id: ' table_id;
  stop;
run;
%mp_abort(iftrue= ("&table_id"="0")
  ,mac=&_program..sas
  ,msg=%str(Invalid table_id provided)
)
 
/* whitelist check - the table_id must also exist in mpe_submit.  The same
  lookup provides the base library & dataset, used further down to source
  the formats.  These are also validated before use in code. */
%let base_lib=;
%let base_ds=;
data _null_;
  set &mpelib..mpe_submit;
  where TABLE_ID="&table_id";
  length base_libds $41;
  base_libds=cats(base_lib,'.',base_ds);
  %mp_validatecol(base_libds,LIBDS,is_base_libds)
  if is_base_libds=1 then do;
    call symputx('base_lib',base_lib);
    call symputx('base_ds',base_ds);
  end;
  else putlog 'ERR' 'OR: Invalid base libds: ' base_libds;
run;
%mp_abort(iftrue= ("&base_lib"="" or "&base_ds"="")
  ,mac=&_program..sas
  ,msg=%str(No valid mpe_submit record found for table_id=&table_id)
)
 
libname loc "&mpelocapprovals/&table_id";
data stagetable;
  set loc.&table_id;
run;
 
%mp_abort(iftrue= (&syscc ne 0)
  ,mac=&_program..sas
  ,msg=%str(syscc=&syscc)
)
 
/* the staged dataset on disk has no formats, so apply those of the base
  table (sourced from mpe_submit above) to the work copy - this drives the
  frontend's Formatted/Unformatted toggle */
%dc_assignlib(READ,&base_lib)
%mp_getcols(&base_lib..&base_ds,outds=work.basecols)
data work.stagefmts;
  set work.basecols;
  length lib $8 ds $32 var $32 fmt $49;
  lib='WORK';
  ds='STAGETABLE';
  var=name;
  fmt=format;
  keep lib ds var fmt;
run;
%mp_applyformats(work.stagefmts)
 
%mp_abort(iftrue= (&syscc ne 0)
  ,mac=&_program..sas
  ,msg=%str(syscc=&syscc after applying base formats)
)
 
%webout(OPEN)
%webout(OBJ,stagetable,missing=STRING)
/* same table again with SAS formats applied */
%webout(OBJ,stagetable,dslabel=fmt_stagetable,fmt=Y,missing=STRING)
%webout(CLOSE)
 
 
%mpeterm()