getstagetable.test.sas

Go to the documentation of this file.

/**
  @file
  @brief testing getstagetable service
 
  <h4> SAS Macros </h4>
  @li mx_execute.sas
  @li mp_assert.sas
  @li mp_assertdsobs.sas
 
**/
 
/**
  * First part - stage some data (to fetch via getstagetable)
  */
data work.sascontroltable;
  action='LOAD';
  message="getstagetable prep";
  libds="&dclib..MPE_X_TEST";
  output;
  stop;
run;
 
proc sql noprint;
select max(primary_key_field) into: maxpk
  from &dclib..mpe_x_test;
 
data work.jsdata;
  set &dclib..mpe_x_test;
  if _n_=1 then do;
    _____DELETE__THIS__RECORD_____='No';
    some_char='getstagetable test';
    some_num=&maxpk+1;
    output;
  end;
  else stop;
run;
 
%mx_execute(&appLoc/services/editors/stagedata,
  viyacontext=&defaultcontext,
  inputdatasets=work.sascontroltable work.jsdata,
  outlib=web1,
  mdebug=&sasjs_mdebug
)
 
%let status=0;
data _null_;
  set web1.sasparams;
  putlog (_all_)(=);
  if status='SUCCESS' then call symputx('status',1);
  call symputx('dsid',dsid);
run;
 
%mp_assert(
  iftrue=(&status=1 and &syscc=0),
  desc=Checking successful submission,
  outds=work.test_results
)
 
/**
  * Now fetch the staged table with getstagetable
  */
data work.iwant;
  table_id="&dsid";
  output;
run;
 
%mx_execute(&appLoc/services/auditors/getstagetable,
  viyacontext=&defaultcontext,
  inputdatasets=work.iwant,
  outlib=web2,
  mdebug=&sasjs_mdebug
)
 
/* the staged table must be returned with our row in it */
%let stagecheck=0;
%let fmtcheck=0;
data _null_;
  set web2.stagetable;
  if some_char='getstagetable test' and some_num=&maxpk+1
  then call symputx('stagecheck',1);
run;
data _null_;
  set web2.fmt_stagetable;
  if some_char='getstagetable test' then call symputx('fmtcheck',1);
run;
 
%mp_assertdsobs(web2.stagetable,
  desc=getstagetable returns the staged table,
  test=EQUALS 1,
  outds=work.test_results
)
%mp_assertdsobs(web2.fmt_stagetable,
  desc=getstagetable returns the formatted staged table,
  test=EQUALS 1,
  outds=work.test_results
)
%mp_assert(
  iftrue=(&stagecheck=1 and &fmtcheck=1),
  desc=Checking staged changes present in both unformatted and formatted outputs,
  outds=work.test_results
)