mpe_refreshtables.test.sas

Go to the documentation of this file.

/**
  @file
  @brief Testing mpe_refreshtables macro
 
  <h4> SAS Macros </h4>
  @li mpe_refreshlibs.sas
  @li mpe_refreshtables.sas
  @li mf_getuniquefileref.sas
  @li mf_mkdir.sas
  @li mp_assert.sas
  @li mp_assertscope.sas
 
  @author 4GL Apps Ltd
  @copyright 4GL Apps Ltd.  This code may only be used within Data Controller
    and may not be re-distributed or re-sold without the express permission of
    4GL Apps Ltd.
 
**/
 
/* create a new library with a demo format catalog, so it always exists */
%let reftstloc=%sysfunc(pathname(&dc_libref))/reftst%mf_getuniquefileref();
%mf_mkdir(&reftstloc)
libname reftst "&reftstloc";
 
data work.reftstfmts;
  length fmtname $32;
  fmtname='REFFMT';
  do start=1 to 10;
    label=cats('Format ',start);
    output;
  end;
run;
proc format cntlin=work.reftstfmts library=reftst.dcfmts;
run;
 
/* register the library in mpe_datacatalog_libs */
%mpe_refreshlibs(lib=REFTST)
 
%mp_assertscope(SNAPSHOT)
%mpe_refreshtables(REFTST)
%mp_assertscope(COMPARE,
  desc=Checking macro variables against previous snapshot
)
 
/* make sure that the process picks up a library that contains a catalog */
proc sql;
create table work.libinfo as
  select a.engine,
    a.libname,
    a.paths,
    a.perms,
    a.owners,
    a.schemas,
    a.libid,
    b.libsize,
    b.table_cnt,
    b.catalog_cnt
  from &mpelib..mpe_datacatalog_libs(where=(&dc_dttmtfmt. lt tx_to)) a
  left join &mpelib..mpe_datastatus_libs(where=(&dc_dttmtfmt. lt tx_to)) b
  on a.libref=b.libref
  where a.libref="REFTST";
 
%let test1=0;
data _null_;
  set work.libinfo;
  call symputx('test1',catalog_cnt);
run;
%mp_assert(
  iftrue=(&test1>0),
  desc=Checking reftst.dcfmts was picked up
)