mv_deletejes.sas
Go to the documentation of this file.
1 /**
2  @file
3  @brief Deletes a Viya Job, if it exists
4  @details If not executed in Studio 5+ will expect oauth token in a global
5  macro variable (default ACCESS_TOKEN).
6 
7  filename mc url "https://raw.githubusercontent.com/sasjs/core/main/all.sas";
8  %inc mc;
9 
10  %mv_createwebservice(path=/Public/test, name=blah)
11  %mv_deletejes(path=/Public/test, name=blah)
12 
13 
14  @param [in] path= ()
15  The full path of the folder containing the Job Execution Service
16  @param [in] name= The name of the Job Execution Service to be deleted
17  @param [in] access_token_var= (ACCESS_TOKEN)
18  The global macro variable to contain the access token
19  @param [in] grant_type= (sas_services)
20  Valid values are "password" or "authorization_code" (unquoted).
21 
22 
23  @version VIYA V.03.04
24  @author Allan Bowe, source: https://github.com/sasjs/core
25 
26  <h4> SAS Macros </h4>
27  @li mp_abort.sas
28  @li mf_getplatform.sas
29  @li mf_getuniquefileref.sas
30  @li mf_getuniquelibref.sas
31  @li mf_isblank.sas
32 
33 **/
34 
35 %macro mv_deletejes(path=
36  ,name=
37  ,access_token_var=ACCESS_TOKEN
38  ,grant_type=sas_services
39  );
40 %local oauth_bearer;
41 %if &grant_type=detect %then %do;
42  %if %symexist(&access_token_var) %then %let grant_type=authorization_code;
43  %else %let grant_type=sas_services;
44 %end;
45 %if &grant_type=sas_services %then %do;
46  %let oauth_bearer=oauth_bearer=sas_services;
47  %let &access_token_var=;
48 %end;
49 
50 %mp_abort(iftrue=(&grant_type ne authorization_code and &grant_type ne password
51  and &grant_type ne sas_services
52  )
53  ,mac=&sysmacroname
54  ,msg=%str(Invalid value for grant_type: &grant_type)
55 )
56 %mp_abort(iftrue=(%mf_isblank(&path)=1)
57  ,mac=&sysmacroname
58  ,msg=%str(path value must be provided)
59 )
60 %mp_abort(iftrue=(%mf_isblank(&name)=1)
61  ,mac=&sysmacroname
62  ,msg=%str(name value must be provided)
63 )
64 %mp_abort(iftrue=(%length(&path)=1)
65  ,mac=&sysmacroname
66  ,msg=%str(path value must be provided)
67 )
68 
69 options noquotelenmax;
70 %local base_uri; /* location of rest apis */
71 %let base_uri=%mf_getplatform(VIYARESTAPI);
72 /* fetch the members of the folder to get the uri */
73 %local fname1;
74 %let fname1=%mf_getuniquefileref();
75 proc http method='GET' out=&fname1 &oauth_bearer
76  url="&base_uri/folders/folders/@item?path=&path";
77 %if &grant_type=authorization_code %then %do;
78  headers "Authorization"="Bearer &&&access_token_var";
79 %end;
80 run;
81 %if &SYS_PROCHTTP_STATUS_CODE=404 %then %do;
82  %put &sysmacroname: Folder &path NOT FOUND - nothing to delete!;
83  %return;
84 %end;
85 %else %if &SYS_PROCHTTP_STATUS_CODE ne 200 %then %do;
86  /*data _null_;infile &fname1;input;putlog _infile_;run;*/
87  %mp_abort(mac=&sysmacroname
88  ,msg=%str(&SYS_PROCHTTP_STATUS_CODE &SYS_PROCHTTP_STATUS_PHRASE)
89  )
90 %end;
91 
92 /* grab the follow on link */
93 %local libref1;
94 %let libref1=%mf_getuniquelibref();
95 libname &libref1 JSON fileref=&fname1;
96 data _null_;
97  set &libref1..links;
98  if rel='members' then call symputx('mref',quote("&base_uri"!!trim(href)),'l');
99 run;
100 
101 /* get the children */
102 %local fname1a;
103 %let fname1a=%mf_getuniquefileref();
104 proc http method='GET' out=&fname1a &oauth_bearer
105  url=%unquote(%superq(mref));
106 %if &grant_type=authorization_code %then %do;
107  headers "Authorization"="Bearer &&&access_token_var";
108 %end;
109 run;
110 %if &SYS_PROCHTTP_STATUS_CODE ne 200 %then %do;
111  %put &=sysmacroname &=SYS_PROCHTTP_STATUS_CODE &=SYS_PROCHTTP_STATUS_PHRASE;
112 %end;
113 %local libref1a;
114 %let libref1a=%mf_getuniquelibref();
115 libname &libref1a JSON fileref=&fname1a;
116 %local uri found;
117 %let found=0;
118 /* %put Getting object uri from &libref1a..items; */
119 data _null_;
120  length contenttype name $1000;
121  set &libref1a..items;
122  if contenttype='jobDefinition' and upcase(name)="%upcase(&name)" then do;
123  call symputx('uri',cats("&base_uri",uri),'l');
124  call symputx('found',1,'l');
125  end;
126 run;
127 %if &found=0 %then %do;
128  %put NOTE:;%put NOTE- &sysmacroname: &path/&name NOT FOUND;%put NOTE- ;
129  %return;
130 %end;
131 proc http method="DELETE" url="&uri" &oauth_bearer;
132  headers
133 %if &grant_type=authorization_code %then %do;
134  "Authorization"="Bearer &&&access_token_var"
135 %end;
136  "Accept"="*/*";/**/
137 run;
138 %if &SYS_PROCHTTP_STATUS_CODE ne 204 %then %do;
139  data _null_; infile &fname2; input; putlog _infile_;run;
140  %mp_abort(mac=&sysmacroname
141  ,msg=%str(&SYS_PROCHTTP_STATUS_CODE &SYS_PROCHTTP_STATUS_PHRASE)
142  )
143 %end;
144 %else %put &sysmacroname: &path/&name deleted;
145 
146 /* clear refs */
147 filename &fname1 clear;
148 libname &libref1 clear;
149 filename &fname1a clear;
150 libname &libref1a clear;
151 
152 %mend mv_deletejes;